Boolean 数据类型_Flash手册

布尔值是 true 或 false 中的一个。ActionScript 也会在适当时将值 true 和 false 转换为 1 和 0。布尔值经常与 ActionScript 语句中通过比较来控制脚本流的逻辑运算符一起使用。

下面的示例将一个文本文件加载到一个 SWF 文件中，如果文本文件加载不正确，则在"输出"面板中显示一条消息，如果成功加载，则显示各个参数。有关详细信息，请参见代码示例中的注释。

var my_lv:LoadVars = new LoadVars();
//success 是一个布尔值
my_lv.onLoad = function(success:Boolean) {
    //如果 success 为 true，则输出 monthNames
    if (success) {
        trace(my_lv.monthNames);
    //如果 success 为 false，则输出消息
    } else {
        trace("unable to load text file");
    }
};
my_lv.load("http://www.helpexamples.com/flash/params.txt");

下面的示例检查用户是否在两个 TextInput 组件实例中输入了值。创建两个布尔变量 userNameEntered 和 isPasswordCorrect，如果这两个变量的求值结果都等于 true，则将一条欢迎消息赋值给 titleMessage String 变量。

// 在舞台上添加两个 TextInput 组件、一个 Label 和一个 Button 组件。
// 三个组件实例都是严格数据类型
var userName_ti:mx.controls.TextInput;
var password_ti:mx.controls.TextInput;
var submit_button:mx.controls.Button;
var welcome_lbl:mx.controls.Label;

//隐藏标签
welcome_lbl.visible = false;

// 创建一个侦听器对象，它与 Button 组件结合使用。
// 单击 Button 时，检查用户名和密码。
var btnListener:Object = new Object();
btnListener.click = function(evt:Object) {
    // 检查用户是否在 TextInput 中输入了至少一个字符
    // 实例和返回布尔值 true/false。
    var userNameEntered:Boolean = (userName_ti.text.length > 0);
    var isPasswordCorrect:Boolean = (password_ti.text == "vertigo");
    if (userNameEntered && isPasswordCorrect) {
        var titleMessage:String = "Welcome " + userName_ti.text + "!";
        welcome_lbl.text = titleMessage;
        //显示标签
        welcome_lbl.visible = true;
    }
};
submit_button.addEventListener("click", btnListener);